w10install/06_Copy2Media.cmd

@echo off
set W10=c:\TEMP\W10
set SOURCES=%W10%\sources
set BOOTFILE=boot.wim
set IMAGEFILE=install.wim
set SCRIPT_SETTINGS=scripts\settings.cmd
set COMPANY_SETTINGS=company\settings.cmd

IF %1.==. GOTO USAGE

echo.
echo =================================
echo Copying all data to Media ...
echo =================================
echo.

set DRIVE=%1

if /I %DRIVE% == C: (
  echo ERROR: cannot use drive %DRIVE% !
  exit /b
)

if NOT EXIST %DRIVE% (
  echo ERROR: drive %DRIVE% not found!
  exit /b
)

echo using drive [ %DRIVE% ] ...
echo.

if NOT EXIST %SOURCES%\%BOOTFILE% (
  echo DOH! no %BOOTFILE% in [ %SOURCES% ] found
  exit /b
)

if NOT EXIST %SOURCES%\%IMAGEFILE% (
  echo DOH! no %IMAGEFILE% in [ %SOURCES% ] found
  exit /b
)

rem =====
rem MAIN
rem =====

echo copying all files in [ %W10% ] to drive %DRIVE% ...
robocopy %W10%\ %DRIVE% /MIR /256 /NDL /R:1 /J /XX

rem check for existence of install.wim in case FAT32 was chosen ...
if NOT EXIST %DRIVE%\sources\%IMAGEFILE% (
  echo ERROR ON COPY: no %IMAGEFILE% in [ %DRIVE%\sources\%IMAGEFILE% ] found!
  echo HINT: FAT32 cannot handle files larger 4 GB!
  exit /b
)

:CONT
if EXIST tools (
  echo.
  echo copying folder [ tools ] to drive %DRIVE% ...
  robocopy tools %DRIVE%\tools /COPY:DT /FFT /XO /256 /NJH /NJS /NDL /R:1 /XF .gitignore
)

if EXIST software (
  echo.
  echo copying folder [ software ] to %DRIVE%\tools ...
  robocopy software %DRIVE%\tools\software /COPY:DT /FFT /XO /MIR /256 /NJH /NJS /NDL /R:1 ^
    /XF *.iso /XF *.txt /XF *.cmd /XF *.csv /XF .gitignore /XD .git
)

for %%P in (drivers scripts source optional personal company apps) do (
  if EXIST %%P (
    echo.
    echo copying folder [ %%P ] to %DRIVE%\tools ...
    robocopy %%P %DRIVE%\tools\%%P /COPY:DT /FFT /XO /MIR /256 /NJH /NJS /NDL ^
      /R:1 /XF .gitignore /XD .git
  )
)

echo.
echo copying autoconfig starter script to %DRIVE% ...
copy /Y image\StartAutoConfig.cmd %DRIVE%\

echo.
echo putting copytools script to %DRIVE% ...
copy /Y image\CopyTools.cmd %DRIVE%\

rem remove hidden attribute from tools folder ...
attrib -H %DRIVE%\tools 

echo.
rem remove passwords from settings.cmd config files ...
for %%A in (
  %DRIVE%\tools\%SCRIPT_SETTINGS%
  %DRIVE%\tools\%COMPANY_SETTINGS%
) do (
  if EXIST %%A (
    tools\searchreplace %%A "^.*SET.*LOCALADMIN_PASSWORD.*=.*" "set localadmin_password=DELETED"
  )
)

echo.
echo ======
echo READY.
echo ======

GOTO END

:USAGE
echo "usage: %0 <DRIVE>"
echo.

:END