@echo off
call check-for-admin
if %ERRORLEVEL% neq 0 exit /b

set OPT=..\optional
set SOFTWARE=..\software
set MSI=emclient-setup.msi
set SETTINGS=..\company\settings.cmd
set emclient_license=0
set EMSERVERIP=168.62.48.183

if NOT EXIST %SOFTWARE%\%MSI% (
  echo ERROR: %SOFTWARE%\%MSI% not found!
  exit /b
)

rem ===================
rem CONFIGFILE CHECK
rem ===================

if NOT EXIST %SETTINGS% (
  echo.
  echo WARNING: %SETTINGS% NOT FOUND
  echo.
) else (
  call %SETTINGS%
)

echo ####### %0 #######

echo installing em-Client ...
cd %SOFTWARE%
@echo on
msiexec /i %MSI% /quiet
@echo off
cd %OPT%

echo removing autostart for em-Client ...
reg delete "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" ^
  /v "eM Client" /f

taskkill /F /IM SystemSettings.exe 2>nul

echo copying link to desktop ...
copy /Y "%PROGRAMDATA%\Microsoft\Windows\Start Menu\Programs\eM Client.lnk" ^
  %PUBLIC%\Desktop

echo refreshing desktop ...
ie4uinit.exe -show

echo disabling automatic updates via W10 firewall ...
netsh advfirewall firewall delete rule name="block_emclient_updates" 2>nul
netsh advfirewall firewall add rule name="block_emclient_updates" ^
  dir=out action=block protocol=tcp localip=any remoteip=%EMSERVERIP% ^
  remoteport=80,443 program="%ProgramFiles(x86)%\eM Client\MailClient.exe"

if emclient_license == 0 (
  echo no em Client license found!
) else (
  echo adding em Client license ...
  "%ProgramFiles(x86)%\eM Client\MailClient.exe" /deactivate
  "%ProgramFiles(x86)%\eM Client\MailClient.exe" /activate %emclient_license%
)

echo ####### %0 #######
pause