@echo off

rem ===================
rem GLOBAL VARS
rem ===================
set TOOLS=c:\tools
set PERSONALFILES_DONE=%LOCALAPPDATA%\.personalfiles_done

rem already done ?
if EXIST %PERSONALFILES_DONE% GOTO END

echo ####### %0 #######

rem TOTALCOMMANDER config ...
mkdir %APPDATA%\GHISLER 1>nul 2>nul

echo copying ini files for TOTALCOMMANDER ...
if EXIST %TOOLS%\personal\WINCMD.ini (
  copy /Y %TOOLS%\personal\WINCMD.ini %APPDATA%\GHISLER
) else (
  copy /Y %TOOLS%\optional\config\WINCMD.ini %APPDATA%\GHISLER
)

rem ftp config file ...
if EXIST %TOOLS%\personal\wcx_ftp.ini (
  copy /Y %TOOLS%\personal\wcx_ftp.ini %APPDATA%\GHISLER
) else (
  copy /Y %TOOLS%\optional\config\wcx_ftp.ini %APPDATA%\GHISLER
)

rem SSH keys ...
if EXIST %TOOLS%\personal (
  echo copying personal SSH keys ...
  copy /Y %TOOLS%\personal\id*.* %USERPROFILE%\.ssh 2>nul
)

rem GIT
if EXIST %TOOLS%\personal\gitconfig (
  echo copying gitconfig ...
  copy /Y %TOOLS%\personal\gitconfig %USERPROFILE%\.gitconfig
)

rem create a statusfile (this codeblock must be executed only once per user) ...
echo 1 >%PERSONALFILES_DONE%

:END

echo ####### %0 #######